Step 2 Build the JSM Commands for the FTP Service

You are here:

Step 2. Build the JSM Commands for the FTP Service

INT002 - Using the FTP Service

In this step, working with function iiiFN02, you will use the template BBJSMXCMD to build the JSM commands to perform the following tasks using the FTP service:

Connect to a FTP site

Set the directory

List the files in the path specified

Quit the FTP site.

Using the BBJSMXCMD template, you will use the following command, keywords and values:

Command	Keyword	Value	Working List
CONNECT	HOST	#S_HOST
LOGIN	USER	#S_USER
LOGIN	PASSWORD	#S_PSWD
CHGDIR	PATH	#S_DIR
LIST	DIR		WL_FILES
QUIT

1. Working with your iiiFN02 function, execute a template BBJSMXCMD:

a. Before you begin position the cursor at the start of the comment line after the YOUR OWN LOGIC HERE comment, then on the Design ribbon, click on the Template Wizard button.

b. From the list of templates select BBJSMXCMD and click on the Execute button.

c. Answer the template questions as shown in the table following:

Question	Answer	Comments
Use this template to build a command in a function generated by JSMXSKEL.	Press Enter to continue	This is an informative panel.
Type in the JSM command you want to build.	CONNECT
How many keywords do you want to specify?	1
Type in the keyword name.	HOST
Type in the value for the HOST keyword.	#S_HOST	The Host value entered on the screen.
Type in the name of a working list if this command uses one.	Press ENTER	No working list is required by this command
Do you wish to enter another JSM command?	Y
Type in the JSM command you want to build.	LOGIN
How many keywords do you want to specify?	2
Type in the keyword name.	USER
Type in the value for the USER keyword.	#S_USER	The User value entered on the screen.
Type in the keyword name.	PASSWORD
Type in the value for the PASSWORD keyword.	#S_PSWD	The Password value entered on the screen.
Type in the name of a working list if this command uses one.	Press ENTER	No working list is required by this command
Do you wish to enter another JSM command?	Y
Type in the JSM command you want to build.	CHGDIR
How many keywords do you want to specify?	1
Type in the keyword name.	PATH
Type in the value for the PATH keyword.	#S_DIR	The path entered on the screen.
Type in the name of a working list if this command uses one.	Press ENTER	No working list is required by this command
Do you wish to enter another JSM command?	Y
Type in the JSM command you want to build.	LIST
How many keywords do you want to specify?	1
Type in the keyword name.	PATH
Type in the value for the PATH keyword.	Blank out the field holding the previous value entered and Press ENTER	This keyword does not require a value.
Type in the name of a working list if this command uses one.	WL_FILES	The working list to get the list of files back.
Do you wish to enter another JSM command?	Y
Type in the JSM command you want to build.	QUIT
How many keywords do you want to specify?	0	This command has no keywords.
Do you wish to enter another JSM command?	N

d. Once the BBJSMXCMD template has completed, you will have all of the required code for working with the FTP service.

Your RDMLX code might appear as:

* BUILD THE JSM COMMAND

#JSMXCMD := CONNECT

EXECUTE SUBROUTINE(KEYWRD) WITH_PARMS(#JSMXCMD HOST #S_HOST)

USE BUILTIN(JSMX_COMMAND) WITH_ARGS(#JSMXHDLE1 #JSMXCMD) TO_GET(#JSMSTS #JSMMSG)

EXECUTE SUBROUTINE(CHECK_STS) WITH_PARMS(#JSMXCMD)

#JSMXCMD := LOGIN

EXECUTE SUBROUTINE(KEYWRD) WITH_PARMS(#JSMXCMD USER #S_USER)

EXECUTE SUBROUTINE(KEYWRD) WITH_PARMS(#JSMXCMD PASSWORD #S_PSWD)

USE BUILTIN(JSMX_COMMAND) WITH_ARGS(#JSMXHDLE1 #JSMXCMD) TO_GET(#JSMSTS #JSMMSG)

EXECUTE SUBROUTINE(CHECK_STS) WITH_PARMS(#JSMXCMD)

#JSMXCMD := CHGDIR

EXECUTE SUBROUTINE(KEYWRD) WITH_PARMS(#JSMXCMD PATH #S_DIR)

USE BUILTIN(JSMX_COMMAND) WITH_ARGS(#JSMXHDLE1 #JSMXCMD) TO_GET(#JSMSTS #JSMMSG)

EXECUTE SUBROUTINE(CHECK_STS) WITH_PARMS(#JSMXCMD)

#JSMXCMD := LIST

EXECUTE SUBROUTINE(KEYWRD) WITH_PARMS(#JSMXCMD PATH *BLANKS)

USE BUILTIN(JSMX_COMMAND) WITH_ARGS(#JSMXHDLE1 #JSMXCMD) TO_GET(#JSMSTS #JSMMSG #WL_FILES)

EXECUTE SUBROUTINE(CHECK_STS) WITH_PARMS(#JSMXCMD)

#JSMXCMD := QUIT

USE BUILTIN(JSMX_COMMAND) WITH_ARGS(#JSMXHDLE1 #JSMXCMD) TO_GET(#JSMSTS #JSMMSG)

EXECUTE SUBROUTINE(CHECK_STS) WITH_PARMS(#JSMXCMD)

Your complete RDML/RDMLX code might appear as follows:

iiiFRM02:

Function Options(*DIRECT)

Begin_Com Role(*EXTENDS #PRIM_FORM) Clientwidth(834) Clientheight(414) Componentversion(2) Left(625) Top(175)

Define_Com Class(#PRIM_LTVW) Name(#ListView1) Columnbuttonheight(27) Componentversion(2) Displayposition(1) Fullrowselect(True) Keyboardpositioning(SortColumn) Left(24) Parent(#COM_OWNER) Showsortarrow(True) Tabposition(1) Top(168) Height(228) Width(673)

Define_Com Class(#PRIM_LVCL) Name(#LVCL1) Displayposition(1) Parent(#ListView1) Source(#STD_QSEL) Widthtype(Remainder)

Define_Com Class(#PRIM_PHBN) Name(#Button1) Displayposition(2) Left(712) Parent(#COM_OWNER) Tabposition(2) Top(168) Caption('Connect')

Define_Com Class(#S_HOST.Visual) Name(#S_HOST) Componentversion(1) Displayposition(3) Height(21) Left(27) Parent(#COM_OWNER) Tabposition(3) Top(13) Usepicklist(False) Width(782)

Define_Com Class(#S_USER.Visual) Name(#S_USER) Componentversion(1) Displayposition(4) Height(21) Left(26) Parent(#COM_OWNER) Tabposition(4) Top(43) Usepicklist(False) Width(419)

Define_Com Class(#S_PSWD.Visual) Name(#S_PSWD) Componentversion(1) Displayposition(5) Height(21) Left(30) Parent(#COM_OWNER) Tabposition(5) Top(72) Usepicklist(False) Width(419)

Define_Com Class(#S_DIR.Visual) Name(#S_DIR) Componentversion(1) Displayposition(6) Height(21) Left(32) Parent(#COM_OWNER) Tabposition(6) Top(101) Usepicklist(False) Width(782)

Define Field(#W_TYPE) Type(*CHAR) Length(1) Desc('Type of file')

Define Field(#W_FILE) Type(*CHAR) Length(80) Colhdg('File Name')

Def_List Name(#WL_FILES) Fields(#W_TYPE #W_FILE) Type(*WORKING) Entrys(*MAX)

Evtroutine Handling(#com_owner.CreateInstance)

Set Com(#com_owner) Caption(*component_desc)

Endroutine

Evtroutine Handling(#Button1.Click)

CLR_LIST NAMED(#WL_FILES)

CLR_LIST NAMED(#ListView1)

EXCHANGE FIELDS(#S_HOST #S_DIR #S_USER #S_PSWD)

CALL PROCESS(*DIRECT) FUNCTION(IIIFN02) PASS_LST(#WL_FILES)

SELECTLIST NAMED(#WL_FILES)

#STD_QSEL := #W_FILE

ADD_ENTRY TO_LIST(#ListView1)

ENDSELECT

Endroutine

End_Com

iiiFN02:

* ====================================================

* Process ........: JMIPRO02

* Function .......: JMIFN02

* Created on .....: 08/11/13 at 15:11:06

* Description ....: Use FTP Service

* Template........: JSMXSKEL

* ====================================================

FUNCTION OPTIONS(*DIRECT) RCV_LIST(#WL_FILES)

DEFINE FIELD(#W_TYPE) TYPE(*CHAR) LENGTH(1) DESC('Type of file')

DEFINE FIELD(#W_FILE) TYPE(*CHAR) LENGTH(80) COLHDG('File Name')

DEF_LIST NAME(#WL_FILES) FIELDS(#W_TYPE #W_FILE) TYPE(*WORKING) ENTRYS(*MAX)

* OPEN JSM AND VERIFY STATUS

USE BUILTIN(JSMX_OPEN) TO_GET(#JSMSTS #JSMMSG #JSMXHDLE1)

EXECUTE SUBROUTINE(CHECK_STS) WITH_PARMS(#JSMXHDLE1)

* BUILD THE SERVICE LOAD COMMAND

#JSMXCMD := 'SERVICE_LOAD'

EXECUTE SUBROUTINE(KEYWRD) WITH_PARMS(#JSMXCMD 'SERVICE' 'FTPSERVICE')

USE BUILTIN(JSMX_COMMAND) WITH_ARGS(#JSMXHDLE1 #JSMXCMD) TO_GET(#JSMSTS #JSMMSG)

EXECUTE SUBROUTINE(CHECK_STS) WITH_PARMS(#JSMXHDLE1)

* YOUR OWN LOGIC HERE

* BUILD THE JSM COMMAND

#JSMXCMD := CONNECT

EXECUTE SUBROUTINE(KEYWRD) WITH_PARMS(#JSMXCMD HOST #S_HOST)

USE BUILTIN(JSMX_COMMAND) WITH_ARGS(#JSMXHDLE1 #JSMXCMD) TO_GET(#JSMSTS #JSMMSG)

EXECUTE SUBROUTINE(CHECK_STS) WITH_PARMS(#JSMXCMD)

#JSMXCMD := LOGIN

EXECUTE SUBROUTINE(KEYWRD) WITH_PARMS(#JSMXCMD USER #S_USER)

EXECUTE SUBROUTINE(KEYWRD) WITH_PARMS(#JSMXCMD PASSWORD #S_PSWD)

USE BUILTIN(JSMX_COMMAND) WITH_ARGS(#JSMXHDLE1 #JSMXCMD) TO_GET(#JSMSTS #JSMMSG)

EXECUTE SUBROUTINE(CHECK_STS) WITH_PARMS(#JSMXCMD)

#JSMXCMD := CHGDIR

EXECUTE SUBROUTINE(KEYWRD) WITH_PARMS(#JSMXCMD PATH #S_DIR)

USE BUILTIN(JSMX_COMMAND) WITH_ARGS(#JSMXHDLE1 #JSMXCMD) TO_GET(#JSMSTS #JSMMSG)

EXECUTE SUBROUTINE(CHECK_STS) WITH_PARMS(#JSMXCMD)

#JSMXCMD := LIST

EXECUTE SUBROUTINE(KEYWRD) WITH_PARMS(#JSMXCMD PATH *BLANKS)

USE BUILTIN(JSMX_COMMAND) WITH_ARGS(#JSMXHDLE1 #JSMXCMD) TO_GET(#JSMSTS #JSMMSG #WL_FILES)

EXECUTE SUBROUTINE(CHECK_STS) WITH_PARMS(#JSMXCMD)

#JSMXCMD := QUIT

USE BUILTIN(JSMX_COMMAND) WITH_ARGS(#JSMXHDLE1 #JSMXCMD) TO_GET(#JSMSTS #JSMMSG)

EXECUTE SUBROUTINE(CHECK_STS) WITH_PARMS(#JSMXCMD)

* UNLOAD SERVICE

#JSMXCMD := 'SERVICE_UNLOAD'

USE BUILTIN(JSMX_COMMAND) WITH_ARGS(#JSMXHDLE1 #JSMXCMD) TO_GET(#JSMSTS #JSMMSG)

EXECUTE SUBROUTINE(CHECK_STS) WITH_PARMS(#JSMXHDLE1)

* CLOSE JSM AND VERIFY STATUS

USE BUILTIN(JSMX_CLOSE) WITH_ARGS(#JSMXHDLE1) TO_GET(#JSMSTS #JSMMSG)

EXECUTE SUBROUTINE(CHECK_STS) WITH_PARMS(#JSMXHDLE1)

RETURN

* Subroutine to build JSM commands. existing JSM command

SUBROUTINE NAME(KEYWRD) PARMS((#W_CMDX *BOTH) (#W_KEYWRD *RECEIVED) (#W_KEYVAL *RECEIVED))

DEFINE FIELD(#W_CMDX) REFFLD(#JSMXCMD)

DEFINE FIELD(#W_KEYWRD) REFFLD(#STD_TEXT)

DEFINE FIELD(#W_KEYVAL) REFFLD(#STD_TEXTL)

#W_CMDX += ' ' + #W_KEYWRD + '(' + #W_KEYVAL + ')'

ENDROUTINE

* Check the status of the JSM command issued

SUBROUTINE NAME(CHECK_STS) PARMS(#W_HDLE)

DEFINE FIELD(#MSGDTA) TYPE(*CHAR) LENGTH(132)

DEFINE FIELD(#W_HDLE) TYPE(*CHAR) LENGTH(4)

IF COND('#JSMSTS *NE OK')

#MSGDTA := 'Error Status Code: ' + #JSMSTS

MESSAGE MSGID(DCM9899) MSGF(DC@M01) MSGDTA(#MSGDTA)

#MSGDTA := 'Error Message: ' + #JSMMSG

MESSAGE MSGID(DCM9899) MSGF(DC@M01) MSGDTA(#MSGDTA)

ENDIF

ENDROUTINE