リストの各エントリー毎に繰り返されるラベル

祖先 - ラベル (PRIM_MD.Label) コントロール (PRIM_MD.Control) コントロール (PRIM_CTRL) オブジェクト (PRIM_OBJT)

詳細

Prim_MD.ListLabel は編集フィールドとしてビジュアライズされた、リスト内の編集フィールドです。
 
各編集フィールドタイプには、個別のエントリーへのアクセスを提供対応する CurrentItem があり、それぞれのエントリーに CurrentItem プロパティ経由でアクセスできるようになります。
 
リスト編集コントロールは、リストのコントロール ビューからラベルがドラッグ アンド ドロップされると必ず作成されます。

例

次の例では、エントリー追加後、ラベルの現在のアイテムに設定されたキャプションが設定されています。
 
ボタンがクリックされると、このボタンのキャプションがラベルのキャプションに追加されます。

Begin_Com Role(*EXTENDS #PRIM_WEB) Height(569) Width(633) Theme(#SYS_THEME) Layoutmanager(#LayoutPage)
 
    Define_Com Class(#PRIM_TBLO) Name(#LayoutPage)
    Define_Com Class(#PRIM_TBLO.Row) Name(#LayoutPageRow) Displayposition(1) Parent(#LayoutPage)
    Define_Com Class(#PRIM_TBLO.Column) Name(#LayoutPageColumn) Displayposition(1) Parent(#LayoutPage)
    Define_Com Class(#PRIM_TBLO.Item) Name(#LayoutPageItem) Column(#LayoutPageColumn) Manage(#List) Parent(#LayoutPage) Row(#LayoutPageRow)
 
    Define_Com Class(#PRIM_TBLO) Name(#LayoutList)
    Define_Com Class(#PRIM_TBLO.Column) Name(#LayoutListColumn1) Displayposition(2) Parent(#LayoutList)
    Define_Com Class(#PRIM_TBLO.Row) Name(#LayoutListRow) Parent(#LayoutList) Displayposition(1)
    Define_Com Class(#PRIM_TBLO.Column) Name(#LayoutListColumn) Parent(#LayoutList) Displayposition(1)
    Define_Com Class(#PRIM_TBLO.Item) Name(#LayoutListItemLeft) Column(#LayoutListColumn) Manage(#ListLabel) Parent(#LayoutList) Row(#LayoutListRow) Marginbottom(6) Marginleft(6) Marginright(6) Margintop(6)
    Define_Com Class(#PRIM_TBLO.Item) Name(#LayoutListItemRight) Column(#LayoutListColumn1) Manage(#ListRaisedButton) Parent(#LayoutList) Row(#LayoutListRow) Marginbottom(6) Marginleft(6) Marginright(6) Margintop(6)
 
    Define_Com Class(#prim_md.List) Name(#List) Parent(#COM_OWNER) Displayposition(1) Tabposition(1) Left(0) Top(0) Height(569) Width(633) Layoutmanager(#LayoutList) Rowheight(79)
    Define_Com Class(#Prim_md.ListLabel) Name(#ListLabel) Parent(#List) Displayposition(2) Tabposition(1) Height(67) Width(305) Left(6) Top(6)
    Define_Com Class(#PRIM_MD.ListRaisedButton) Name(#ListRaisedButton) Caption('BUTTON') Displayposition(1) Dragstyle(None) Left(323) Parent(#List) Tabposition(3) Top(6) Height(67) Width(304)
 
 
        Evtroutine Handling(#Com_owner.CreateInstance)
 
            Begin_Loop Using(#xDemoNumber) To(10)
 
                Add_Entry To_List(#List)
 
                #ListLabel.CurrentItem.Caption := 'Label:' + #xDemoNumber.AsString
 
                #ListRaisedButton.CurrentItem.Caption := 'Button:' + #xDemoNumber.AsString
 
            End_Loop
 
        Endroutine
 
 
        Evtroutine Handling(#ListRaisedButton.Click)
 
            #ListLabel.CurrentItem.Caption := ('&1 - &2 &3').Substitute( #ListLabel.CurrentItem.Caption #ListRaisedButton.CurrentItem.Caption 'Clicked' )
 
        Endroutine
End_Com

ﾌﾟﾛﾊﾟﾃｨ

イベント

ﾒｿｯﾄﾞ

参照

すべてのコンポーネント クラス

テクニカルリファレンス

EPC142030 February 2019