マテリアルデザインのスライダー コントロール

祖先 - コントロール (PRIM_MD.Control) コントロール (PRIM_CTRL) オブジェクト (PRIM_OBJT)

詳細

スライダーは、バーに沿って数値を調整できるようにする入力コントロールです。
 
スライダー値の範囲は、MaximumValue と MinimumValue プロパティを使用して設定できます。

例

次の例では、Web ページの背景用の RGB の色をコントロールする 3 つのスライダーが存在します。各スライダーの範囲は 0 から 255 です。
 

Begin_Com Role(*EXTENDS #PRIM_WEB) Theme(#SYS_THEME) Width(801) Style(#StyleBackground) Layoutmanager(#LayoutMain)
 
    Define_Com Class(#prim_vs.Style) Name(#StyleBackground) Backgroundbrush(#BrushBackground)
    Define_Com Class(#PRIM_VS.SolidBrush) Name(#BrushBackground)
 
    Define_Com Class(#PRIM_TBLO) Name(#LayoutMain)
    Define_Com Class(#PRIM_TBLO.Column) Name(#LayoutMainColumn1) Displayposition(1) Parent(#LayoutMain) Units(Pixels) Width(330)
    Define_Com Class(#PRIM_TBLO.Column) Name(#LayoutMainColumn3) Displayposition(2) Parent(#LayoutMain)
    Define_Com Class(#PRIM_TBLO.Row) Name(#LayoutMainRow1) Displayposition(1) Parent(#LayoutMain) Height(50) Units(Pixels)
    Define_Com Class(#PRIM_TBLO.Row) Name(#LayoutMainRow2) Displayposition(2) Parent(#LayoutMain) Height(50) Units(Pixels)
    Define_Com Class(#PRIM_TBLO.Row) Name(#LayoutMainRow3) Displayposition(3) Parent(#LayoutMain) Height(50) Units(Pixels)
    Define_Com Class(#PRIM_TBLO.Row) Name(#LayoutMainRow4) Displayposition(4) Parent(#LayoutMain)
    Define_Com Class(#PRIM_TBLO.Item) Name(#LayoutMainItem1) Alignment(TopCenter) Column(#LayoutMainColumn1) Manage(#SliderBlue) Parent(#LayoutMain) Row(#LayoutMainRow3)
    Define_Com Class(#PRIM_TBLO.Item) Name(#LayoutMainItem2) Alignment(TopCenter) Column(#LayoutMainColumn1) Manage(#SliderGreen) Parent(#LayoutMain) Row(#LayoutMainRow2)
    Define_Com Class(#PRIM_TBLO.Item) Name(#LayoutMainItem3) Alignment(TopCenter) Column(#LayoutMainColumn1) Manage(#SliderRed) Parent(#LayoutMain) Row(#LayoutMainRow1)
 
    Define_Com Class(#PRIM_MD.Slider) Name(#SliderBlue) Displayposition(3) Parent(#COM_OWNER) Tabposition(3) Themedrawstyle('Text(33,150,243,1)') Value(100) Increment(1) Top(100) Width(365) Height(50) Type(Discrete)
    Define_Com Class(#PRIM_MD.Slider) Name(#SliderGreen) Displayposition(2) Parent(#COM_OWNER) Tabposition(2) Themedrawstyle('Text(76,175,80,1)') Value(100) Increment(1) Top(50) Width(365) Height(50) Type(Discrete)
    Define_Com Class(#PRIM_MD.Slider) Name(#SliderRed) Displayposition(1) Parent(#COM_OWNER) Tabposition(1) Themedrawstyle('Text(244,67,54,1)') Value(100) Increment(1) Width(365) Height(50) Type(Discrete)
 
        Evtroutine Handling(#COM_OWNER.CreateInstance)
 
            #SliderRed.Value #SliderGreen.Value #SliderBlue.Value := 255
 
            #COM_OWNER.SliderChanged
 
        Endroutine
 
        Evtroutine Handling(#SliderRed.Changed #SliderGreen.Changed #SliderBlue.Changed)
 
            #COM_OWNER.SliderChanged
 
        Endroutine
 
        Mthroutine Name(SliderChanged)
 
            #BrushBackground.Color := ('&1:&2:&3').Substitute( #SliderRed.Value.AsString #SliderGreen.Value.AsString #SliderBlue.Value.AsString )
 
        Endroutine
 
End_Com

ﾌﾟﾛﾊﾟﾃｨ

イベント

ﾒｿｯﾄﾞ

参照

すべてのコンポーネント クラス

テクニカルリファレンス

EPC142030 February 2019